Platform testing software
Home
Up

The DIY motion platform III is moved by three actuators, one front and two rear.

To check the actuator center point and travel for each actuator, the following program asks for the 3 actuator values and then sends these to the parallel port.
Caution: The program output will result in sudden step response.  I don't recommend steps larger than 100 when full drive is enabled.

10 OUT 888,128
20 OUT 890,11
30 out 890,4
40 out 890,11
50 input "dac1 value ", A
60 input "dac2 value ", B
70 input "dac3 value ", C
80 print""
120 Out 888,A
130 Out 890,10
140 out 890,11
150 Out 888,B
160 Out 890,3
170 out 890,11
180 Out 888,C
190 Out 890,15
200 out 890,11
220 GOTO 50

Notes:
In my drive system, there is inversion in the signal chain.
sending 00 will set the actuator in the top position
sending FF will set the actuator in the bottom position

DAC1 corresponds to MOTOR A   on the electrical drive PCB.
DAC2 corresponds to MOTOR B   on the electrical drive PCB.
DAC3 corresponds to MOTOR C   on the electrical drive PCB.
 
MOTOR A is the front actuator
MOTOR B is the right -rear actuator
MOTOR C is the left -rear actuator

Pitch-up is therefore accomplished by moving the front actuator up, and the two rear actuators simultaneously down.
Roll right is done by moving right-rear actuator down, and left-rear actuator up.
Heave up is done by moving all three actuators up.

To test the platform on these three different motions, I have written a test software that produces a sine shaped waveform. By sending the waveform to the three actuators in above ways, pitch, roll or heave can be checked. Note that delay values may need modification depending on PC speed.

10 OUT 888,128
20 OUT 890,11
30 out 890,4
40 out 890,11
'send 128 middle position to all DAC's
50 P=100:A=80
'P is number of points per period, A is amplitude
60 For K=1 to P
70 S=A*(cos((2*3.14*K)/P))
80 If K<=0.5*P then L=20000
'20000 is time between one point at 1st half cosine
90 If K>0.5*P then L=20000
'20000 is time between one point at 2nd half cosine
100 For I=1 to L
110 Next I
120 Out 888,128+S
130 Out 890,10
140 out 890,11
150 Out 888,128+S
160 Out 890,3
170 out 890,11
180 Out 888,128+S
'this produces heave motion
190 Out 890,15
200 out 890,11
210 Next K
220 GOTO 60

following modifications are possible:

80 If K<=0.5*P then L=20000
90 If K>0.5*P then L=3000
'this produces fast up, slow down

80 If K<=0.5*P then L=3000
90 If K>0.5*P then L=20000
'this produces slow up, fast down

120 Out 888,128+S
130 Out 890,10
140 out 890,11
150 Out 888,128-S
160 Out 890,3
170 out 890,11
180 Out 888,128-S
'this produces pitch motion
190 Out 890,15
200 out 890,11

120 Out 888,128
130 Out 890,10
140 out 890,11
150 Out 888,128+S
160 Out 890,3
170 out 890,11
180 Out 888,128-S 
'this produces roll motion
190 Out 890,15
200 out 890,11